You are here:

コンテナへの格納

変数をコンテナに格納するには、put、setおよびgetコマンドを使用します。その他のいくつかのコマンドを利用して、コンテナ内の値を変更することもできます。

put ... intoコマンドを使うと、コンテナに値を割り当てることができます。

put 5 into count

put true into global peace

put customerName into word 2 of line 6 of customerStatement

setコマンドは、これと同じことを実行できます。

set count = 5

set global peace to be true

set word 2 of line 6 of customerStatement to customerName

技術トピック
構文：put source into container set container [= \| to {be {equal to}} \| equal] source

技術トピック

構文：put source into container

set container [= | to {be {equal to}} | equal] source

（setコマンドではなく）putコマンドは、intoの代わりにbeforeまたはafterを指定することで、コンテナの前後に値を追加できます。

put "flower" into wordToMakePlural -- flower

put "s" after wordToMakePlural -- flowers

put heading & return before reportBody

put " " & customerLastName after word 2 of line 6 of customerStatement

put "$" before character firstDigit of Amount

技術トピック
構文：put source [before \| after] container

一度に複数の値を格納する

putおよびsetコマンドは、どちらも一度に複数のコンテナに複数の値を格納できます。これを行うには、コンテナをコンマで区切り、丸括弧か波括弧で囲んで列記します。ソースの値がリストではない単一の値の場合は、その値は送り先のすべてのコンテナに割り当てられます。

put zero into (a,b,c) -- a、b、cをすべて0に設定します

set (startTime, endTime) to "noon"

ソースの値がリストの場合は、ソースリストの連続するアイテムは、送り先の各コンテナに順番に割り当てられます。余分な値は無視されます。

put (1,2,3) into (a,b,c) -- aを1に、bを2に、cを3に設定します

set (x,y) to (y,x) -- xとyの値が入れ替わります

ソースの値を格納するためのコンテナを指定しない場合は、ソース値はスキップされます。

put (1,2,3) into (a,,c)-- aを1に、cを3に設定します（2は無視されます）

put "html://foo/bar" split by "/" into (scheme,,root,leaf)

ソースリストの最後に余る値は、末尾のコンテナの後に「...」（ドット3つ）を用いて、単一のコンテナに集めることができます。

put (1,2,3,4) into (a,b...) -- aを1に、bを(2,3,4)に設定します

getコマンドは、値にアクセスするための別の方法を提供します。その後、その値はitと呼ぶことができます:

get the last word of address

if it is "DC" then shipNow

実際には、itはaskやanswer、convert、readコマンド、および「repeat with each」形式のrepeatコマンドなど、get以外の複数のコマンドから値を格納されるローカル変数であることに注意が必要です（「it」についてを参照）。

技術トピック
構文： get source

add、subtract、multiply、divide、insert、replace、deleteコマンドや、一部の形式のconvert、read、sort、split、joinコマンドなど、いくつかのその他のコマンドでもコンテナのコンテンツを変更できます。

add qty to item productNum of inventoryQty

divide profit by shareholderCount

convert lastUpdate to long date

This topic was last updated on 2月 01, 2019, at 11:13:23 午前.